DELETE WIDGET-POOL statement

Deletes a defined widget pool.

Syntax

DELETE WIDGET-POOL [ pool-name ][ NO-ERROR ]

pool-name

The name of a defined dynamic widget pool. If you omit pool-name, the statement deletes the unnamed pool most recently created in the current or a calling procedure or class-based method.

NO-ERROR

The NO-ERROR option is used to prevent the statement from raising ERROR and displaying error messages.

Example

The following example creates a named widget pool and lets you add buttons to it. When you choose Delete Buttons, the widget pool is deleted. (Therefore all the buttons in the pool are also deleted.) Similarly, when you choose Quit to exit the procedure the widget pool is also deleted. Because the pool is persistent, it remains allocated for the rest of your session if you do not delete it.

r-widpl.p

DEFINE VARIABLE wh AS HANDLE NO-UNDO.

DEFINE BUTTON b_create LABEL "Create Button".
DEFINE BUTTON b_del    LABEL "Delete Buttons".
DEFINE BUTTON b_quit   LABEL "Quit"
  TRIGGERS:
    ON CHOOSE DO:
      IF VALID-HANDLE(wh) THEN
        DELETE WIDGET-POOL "new-buttons".
      QUIT.
    END.
  END.
  
DEFINE FRAME butt-frame
  b_create b_del b_quit
  WITH ROW SCREEN-LINES - 2.

DEFINE FRAME new-buttons
  WITH SIZE 76 BY 11 CENTERED ROW 2 TITLE "New Buttons".

ON CHOOSE OF b_create IN FRAME butt-frame DO:
  STATUS INPUT "Press RETURN to select a new button".
  IF wh = ? OR NOT VALID-HANDLE(wh) THEN
    CREATE WIDGET-POOL "new-buttons" PERSISTENT.
  CREATE BUTTON wh IN WIDGET-POOL "new-buttons" ASSIGN
    FRAME     = FRAME new-buttons:HANDLE
    ROW       = RANDOM(2, 9)
    COLUMN    = RANDOM(2, 58)
    LABEL     = "BUTTON " + STRING(etime)
    SENSITIVE = TRUE
    VISIBLE   = TRUE
    MOVABLE   = TRUE
    TRIGGERS:
      ON CHOOSE PERSISTENT RUN dispmsg.
    END.
END.

ON CHOOSE OF b_del IN FRAME butt-frame DO:
  IF VALID-HANDLE(wh) THEN
    DELETE WIDGET-POOL "new-buttons".
  STATUS INPUT.
END.

ENABLE b_create b_del b_quit WITH FRAME butt-frame.
WAIT-FOR CHOOSE OF b_quit IN FRAME butt-frame.

PROCEDURE dispmsg:
  MESSAGE "You chose button " SELF:LABEL.
END PROCEDURE.

Notes

• When you delete a widget pool, all widgets in that pool are automatically deleted.
• If you do not delete a non-persistent widget pool, it is deleted when the procedure or method that created it ends. If you do not delete a persistent widget pool, it is deleted when the session ends.
• All named widget pools are globally scoped. While a named widget pool is allocated, any procedure or method within the same process can access that widget pool. If you try to delete a named widget pool that does not exist, the AVM raises the ERROR condition.

See also

CREATE WIDGET-POOL statement, DELETE WIDGET statement, NO-ERROR option