FILE-INFO system handle

A handle to an operating system file.

Syntax

FILE-INFO [ :attribute ]

attribute: Specifies an attribute of the FILE-INFO handle.

Attributes

FILE-CREATE-DATE attribute	FILE-CREATE-TIME attribute	FILE-MOD-DATE attribute
FILE-MOD-TIME attribute	FILE-NAME attribute	FILE-SIZE attribute
FILE-TYPE attribute	FULL-PATHNAME attribute	HANDLE attribute
INSTANTIATING-PROCEDURE attribute	PATHNAME attribute	TYPE attribute

Example

After you set the value of the FILE-NAME attribute, you can read the values of the other attributes. For example:

r-osfile.p

DEFINE VARIABLE os-file AS CHARACTER NO-UNDO FORMAT "x(60)" LABEL "File".

REPEAT:
  SET os-file WITH FRAME osfile-info.
  FILE-INFO:FILE-NAME = os-file.
  DISPLAY FILE-INFO:FULL-PATHNAME FORMAT "x(60)" LABEL "Full Path"
    FILE-INFO:PATHNAME FORMAT "x(60)" LABEL "Path"
    FILE-INFO:FILE-TYPE LABEL "Type"
    WITH FRAME osfile-info SIDE-LABELS TITLE "OS File Info".
END.

Notes

The FILE-NAME, FULL-PATHNAME, and PATHNAME attributes can hold names that contain Unicode characters. See Internationalize ABL Applications for more information about Unicode.
You cannot use the FILE-INFO handle to by-pass operating system security. You must have read access to the file and the directory that contains it to obtain information through FILE-INFO.
These attributes return the Unknown value (?) until they are set, and also if the specified file cannot be found or you do not have permission to access the file.
If you set the FILE-NAME attribute to a relative pathname, the FILE-INFO handle searches the current PROPATH to locate the file.
The FILE-TYPE attribute returns a string containing exactly one of the following file type characters:
- D — If the file is a directory
- F — If the file is a standard file or FIFO pipe (UNIX systems)
- M — If the file is a member of an ABL procedure library
- S — If the file is a special device (UNIX systems)
- X — If the file type is unknown (contact your Progress Software Corporation Technical Support representative when you receive this value)
The attribute string can contain any of the following file type characters:
- H — If the file is hidden
- L — If the file is a symbolic link (UNIX systems)
- P — If the file is a pipe file (UNIX systems)
- R — If the file is readable
- W — If the file is writable
The FULL-PATHNAME attribute returns the absolute pathname of the file specified in the FILE-NAME attribute.
If the FILE-NAME attribute contains a simple filename or relative pathname, the PATHNAME attribute contains the pathname of the specified file starting with the directory on the PROPATH where it is found. Otherwise, the PATHNAME attribute contains the absolute pathname specified in the FILE-NAME attribute.
The TYPE attribute returns the widget type, PSEUDO-WIDGET.