INPUT function

References the value of a field in a frame. For example, if you use the PROMPT-FOR statement to get input from the user, PROMPT-FOR stores that information in the screen buffer. You can use the INPUT function to refer to that information.

Syntax

INPUT [ FRAME frame]field

FRAME frame

The name of the frame that contains the field named by the field argument. If you do not name a frame, the INPUT function starts with the current frame and searches outward until it finds the field you name with the field argument.

field

The name of a field or variable whose value is stored in the screen buffer. The specified field must be viewed as a fill-in or text widget.

Example

This procedure displays the current CreditLimit for a Customer. The PROMPT-FOR statement prompts the user for a new CreditLimit value and stores the supplied data in the screen buffer. The procedure uses the INPUT function to point to the data in that buffer.

r-input.p

FOR EACH Customer:
  DISPLAY Customer.CustNum Customer.Name Customer.CreditLimit 
    LABEL "Current credit limit"
    WITH FRAME a 1 DOWN ROW 1.
  PROMPT-FOR Customer.CreditLimit LABEL "New credit limit" 
    WITH SIDE-LABELS NO-BOX ROW 10 FRAME b.
  IF INPUT FRAME b Customer.CreditLimit <> Customer.CreditLimit THEN DO:
    DISPLAY "Changing max credit of" Customer.Name SKIP
      "from" Customer.CreditLimit "to" INPUT FRAME b Customer.CreditLimit
      WITH FRAME c ROW 15 NO-LABELS.
    Customer.CreditLimit = INPUT FRAME b Customer.CreditLimit.
  END.
  ELSE DISPLAY "No change in credit limit" WITH FRAME d ROW 15.
END.

If the user enters a new value, the procedure displays a message that the value has been changed. If the user enters the same value, the procedure displays a message that the credit-limit has not been changed.

Notes

• If you use a field or variable that is referenced with INPUT in more than one frame, then ABL uses the value in the frame most recently introduced in the procedure. To ensure that you are using the appropriate frame, use the FRAME option with the INPUT function to reference a particular frame.
• If you use the INPUT function for a character field whose format contains fill characters, then the value of the function does not contain the fill characters. The fill characters are not stored in the database field or variable, but are instead supplied during display formatting of the data.